Hull
    name = "SH_SPATIAL_FLUX"
    description = "SH_SPATIAL_FLUX_DESC"
    speed = 80
    fuel = 8
    NoDefaultFuelEffect
    stealth = 15
    structure = 3
    slots = [
        Slot type = External position = (0.40, 0.50)
        Slot type = External position = (0.60, 0.50)
    ]
    buildCost = 11 * [[FLEET_UPKEEP_MULTIPLICATOR]] * [[SHIP_HULL_COST_MULTIPLIER]]
    buildTime = 2
    tags = [ "PEDIA_HULL_LINE_ROBOTIC" "GREAT_FUEL_EFFICIENCY" ]
    location = And [
        Contains And [
            Building name = "BLD_SHIPYARD_BASE"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_ORBITAL_DRYDOCK"
            OwnedBy empire = Source.Owner
        ]
        OwnedBy empire = Source.Owner
    ]
    effectsgroups = [
        EffectsGroup
            scope = Source
            activation = Not Stationary
            accountinglabel = "SPATIAL_FLUX_MALUS"
            effects = SetStealth value = Value - 30
        EffectsGroup
            scope = Source
            activation = Not Aggressive
            accountinglabel = "SPATIAL_FLUX_BONUS"
            effects = SetStealth value = Value + 10 + (10 * Statistic If condition = OwnerHasTech name = "SPY_STEALTH_PART_1" ) + (10 * Statistic If condition = OwnerHasTech name = "SPY_STEALTH_PART_2" ) + (10 * Statistic If condition = OwnerHasTech name = "SPY_STEALTH_PART_3" ) + (10 * Statistic If condition = OwnerHasTech name = "SPY_STEALTH_4" )

        [[GREAT_FUEL_EFFICIENCY]]
        [[ADD_HULL_FUEL_TO_MAX_FUEL_METER]]
        [[AVERAGE_BASE_FUEL_REGEN]]
        [[REGULAR_HULL_DETECTION]]
        [[SCAVANGE_FUEL_UNOWNED]]
        [[UNOWNED_GOOD_VISION]]
        [[UNOWNED_MOVE]]
    ]
    icon = "icons/ship_hulls/spatial_flux_hull_small.png"
    graphic = "hulls_design/spatial_flux_hull.png"

#include "robotic.macros"

#include "../ship_hulls.macros"

#include "/scripting/common/upkeep.macros"
